@ECHO OFF

ECHO カレントディレクトリ直下のファイル名（拡張子あり）を全て列挙する
ECHO FOR %%A IN (*) DO ECHO %%~nxA
FOR %%A IN (*) DO ECHO %%~nxA
ECHO.
ECHO.

ECHO カレントディレクトリ直下のファイル名（拡張子なし）を全て列挙する
ECHO FOR %%A IN (*) DO ECHO %%~nA
FOR %%A IN (*) DO ECHO %%~nA
ECHO.
ECHO.

ECHO カレントディレクトリ直下のファイルパスを全て列挙する
ECHO FOR %%A IN (*) DO ECHO %%~fA
FOR %%A IN (*) DO ECHO %%~fA
ECHO.
ECHO.

ECHO カレントディレクトリ直下のディレクトリ名を全て列挙する
ECHO FOR /D %%A IN (*) DO ECHO %%A
FOR /D %%A IN (*) DO ECHO %%A
ECHO.
ECHO.

ECHO カレントディレクトリ直下のディレクトリパスを全て列挙する
ECHO FOR /D %%A IN (*) DO ECHO %%~fA
FOR /D %%A IN (*) DO ECHO %%~fA
ECHO.
ECHO.

ECHO カレントディレクトリ配下のファイル名（拡張子あり）を全て列挙する
ECHO FOR /R %%A IN (*) DO ECHO %%~nxA
FOR /R %%A IN (*) DO ECHO %%~nxA
ECHO.
ECHO.

ECHO カレントディレクトリ配下のファイル名（拡張子なし）を全て列挙する
ECHO FOR /R %%A IN (*) DO ECHO %%~nA
FOR /R %%A IN (*) DO ECHO %%~nA
ECHO.
ECHO.

ECHO カレントディレクトリ配下のファイルパスを全て列挙する
ECHO FOR /R %%A IN (*) DO ECHO %%~fA
FOR /R %%A IN (*) DO ECHO %%~fA
ECHO.
ECHO.

ECHO カレントディレクトリ直下のconfig.txtファイルの内容を抽出する
ECHO   #で始まる行をコメント行とする
ECHO   「,」、「半角スペース」を区切り文字とする
ECHO   %%Aには2盤目のトークンが設定される
ECHO   %%Bには3盤目のトークンが設定される
ECHO   %%Cには3盤目のトークン以降の文字列が区切られずに設定される
ECHO %~dp0config.txtの内容
ECHO ==
type config.txt
ECHO.
ECHO ==
ECHO FOR /F "eol=# tokens=2,3* delims=, " %%A IN (config.txt) DO ECHO (1)=[%%A] (2)=[%%B] (3)=[%%C]
FOR /F "eol=# tokens=2,3* delims=, " %%A IN (config.txt) DO ECHO (1)=[%%A] (2)=[%%B] (3)=[%%C]
ECHO.
ECHO.

ECHO コマンドの結果を入力値として使用する
ECHO   usebackqオプションを設定し、一重引用符で囲むことでコマンド実行を有効にする
ECHO   DIRコマンドは以下のオプションを設定している
ECHO     /b：ファイル名のみ表示する
ECHO     /a：ディレクトリ、システムファイルを除外する
ECHO     /o：名前で昇順ソートする
ECHO FOR /F "usebackq" %%A IN (`DIR ".\Root\Temp" /b /a:-d-s /o:n`) DO ECHO %%A
FOR /F "usebackq" %%A IN (`DIR ".\Root\Temp" /b /a:-d-s /o:n`) DO ECHO %%A
ECHO.
ECHO.

PAUSE